// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © jeetbeez

//  _____                 __    __                               
// /\___ \               /\ \__/\ \                             
// \/__/\ \     __     __\ \ ,_\ \ \____     __     __   ____   
//    _\ \ \  /'__`\ /'__`\ \ \/\ \ '__`\  /'__`\ /'__`\/\_ ,`\ 
//   /\ \_\ \/\  __//\  __/\ \ \_\ \ \L\ \/\  __//\  __/\/_/  /_
//   \ \____/\ \____\ \____\\ \__\\ \_,__/\ \____\ \____\ /\____\
//    \/___/  \/____/\/____/ \/__/ \/___/  \/____/\/____/ \/____/

//@version=5
indicator("Linear Regression Trend Channel", shorttitle="LinRegTC [Jeetbeez]", overlay=true)

// Parameters
linRegPeriod = input.int(100, 'Linear Regression Length', minval=1)
linRegSource = input.source(close, 'Linear Regression Source')
tf = input.timeframe(title="Timeframe for High/Low", defval="W", options=["D", "W", "M", "3M", "6M", "12M"])
lineColor = input.color(color.gray, 'Linear Regression Color')
labelPriceColor = input.color(color.gray, 'Label Price Color')
HLcolor = input.color(color.blue, title="High/Low Color")
showHorizontal = input.bool(true, 'Show Horizontal Line')
showHL = input.bool(false, title="Show High/Low")
showPrice = input.bool(true, 'Show Price')

// High and Low calculations
High = request.security(syminfo.tickerid, tf, high)
Low = request.security(syminfo.tickerid, tf, low)

// Functions
calcSlopeIntercept(src, len) =>
    max_bars_back(src, 5000)
    Periods = 0.0
    Values = 0.0
    PeriodsSquared = 0.0
    ValuesPeriods = 0.0
    for i = 0 to len - 1
        val = src[i]
        period = i + 1.0
        Periods += period
        Values += val
        PeriodsSquared += period * period
        ValuesPeriods += val * period
    slope = (len * ValuesPeriods - Periods * Values) / (len * PeriodsSquared - Periods * Periods)
    intercept = Values / len - slope * Periods / len + slope
    [slope, intercept]

calcDeviation(src, len, slope, intercept) =>
    dev = 0.0
    periods = len - 1
    currentValue = intercept
    for i = 0 to periods
        price = src[i]
        price -= currentValue
        dev += price * price
        currentValue += slope
    math.sqrt(dev / periods)

crossingLevel(current, level) =>
    (level > current and level < current[1]) or (level < current and level > current[1])

drawHorizontal(price, lineColor, lineStyle) =>
    if showHorizontal
        line_style = line.style_solid
        if lineStyle == 'Dotted'
            line_style := line.style_dotted
        else if lineStyle == 'Dashed'
            line_style := line.style_dashed
        line.new(bar_index, price, bar_index + 15, price, xloc.bar_index, extend.none, lineColor, line_style, 2)
        if showPrice
            label.new(bar_index + 15, price, str.tostring(price, format.mintick), color=labelPriceColor, textcolor=color.white, size=size.small, style=label.style_label_left, textalign=text.align_right)

drawLinearRegressionLine(startIdx, startPrice, endIdx, endPrice, lineColor, lineStyle) =>
    line_style = line.style_solid
    if lineStyle == 'Dotted'
        line_style := line.style_dotted
    else if lineStyle == 'Dashed'
        line_style := line.style_dashed
    line.new(startIdx, startPrice, endIdx, endPrice, xloc.bar_index, extend.none, lineColor, line_style, 2)
    if showPrice and not showHorizontal
        label.new(endIdx, endPrice, str.tostring(endPrice, format.mintick), color=labelPriceColor, textcolor=color.white, size=size.small, style=label.style_label_left, textalign=text.align_right)

deleteAllLinesAndLabels() =>
    for lineId in line.all
        line.delete(lineId)
    for labelId in label.all
        label.delete(labelId)

processLinRegLevel(level, color, style, startPrice, endPrice, stdDev) =>
    drawLinearRegressionLine(bar_index - linRegPeriod + 1, startPrice + level * stdDev, bar_index, endPrice + level * stdDev, color, style)
    drawLinearRegressionLine(bar_index - linRegPeriod + 1, startPrice - level * stdDev, bar_index, endPrice - level * stdDev, color, style)
    drawHorizontal(endPrice + level * stdDev, color, style)
    drawHorizontal(endPrice - level * stdDev, color, style)
    if crossingLevel(close, endPrice + level * stdDev)
        alert('LRTC: ' + syminfo.ticker + ' crossing upper deviation line ' + str.tostring(level) + ' : ' + str.tostring(endPrice + level * stdDev, format.mintick))
    if crossingLevel(close, endPrice - level * stdDev)
        alert('LRTC: ' + syminfo.ticker + ' crossing lower deviation line ' + str.tostring(level) + ' : ' + str.tostring(endPrice - level * stdDev, format.mintick))

// Main Calculation
[slope, intercept] = calcSlopeIntercept(linRegSource, linRegPeriod)
stdDev = calcDeviation(linRegSource, linRegPeriod, slope, intercept)
startPrice = intercept + slope * (linRegPeriod - 1)
endPrice = intercept

// Draw Lines and Labels
deleteAllLinesAndLabels()
drawLinearRegressionLine(bar_index - linRegPeriod + 1, startPrice, bar_index, endPrice, lineColor, 'Solid')
if not showHorizontal and showPrice
    label.new(bar_index, endPrice, str.tostring(endPrice, format.mintick), color=labelPriceColor, textcolor=color.white, size=size.small, style=label.style_label_left, textalign=text.align_right)
drawHorizontal(endPrice, lineColor, 'Solid')
if crossingLevel(close, endPrice)
    alert('LRTC: ' + syminfo.ticker + ' crossing base line : ' + str.tostring(endPrice, format.mintick))
processLinRegLevel(1, lineColor, 'Dashed', startPrice, endPrice, stdDev)
processLinRegLevel(2, lineColor, 'Solid', startPrice, endPrice, stdDev)
processLinRegLevel(3, lineColor, 'Dotted', startPrice, endPrice, stdDev)

// High/Low Lines and Labels
var line hLine = na
var line lLine = na
var label hLabel = na
var label lLabel = na

if showHL and barstate.islast
    if not na(hLine)
        line.delete(hLine)
    if not na(hLabel)
        label.delete(hLabel)
    if not na(lLine)
        line.delete(lLine)
    if not na(lLabel)
        label.delete(lLabel)
    hLine := line.new(x1=bar_index - 100, y1=High, x2=bar_index + 25, y2=High, color=HLcolor, width=2, style=line.style_solid, extend=extend.both)
    if showPrice
        hLabel := label.new(x=bar_index + 25, y=High, text=str.tostring(High, format.mintick), style=label.style_label_left, color=HLcolor, textcolor=color.white, size=size.small)
    lLine := line.new(x1=bar_index - 100, y1=Low, x2=bar_index + 25, y2=Low, color=HLcolor, width=2, style=line.style_solid, extend=extend.both)
    if showPrice
        lLabel := label.new(x=bar_index + 25, y=Low, text=str.tostring(Low, format.mintick), style=label.style_label_left, color=HLcolor, textcolor=color.white, size=size.small)